% this is /athe/a/toni/papers/semiotes/grammar.bnf

% cut and pasted from the grammar.tex file in /sthenias/a/the_agora/code/trade/semiotes/manual; 
% make sure this is identical to the backed-up one from last fall (can also check
% slide for 341).
% Kazic, 17.1.02.





% This is a BNF specification of a left-recursive, context-free grammar for the
% Glossa.  It is in ASCII with tab-delimited fields, one rule/line.
% With very little alteration it should be suitable as input for a look-ahead 
% 1 character left-right parser generator, such as YACC and CUP. 

% I haven't included definitions of things like alphanumeric characters,
% upper and lower case, numerals, etc., thinking those are pretty obvious.
% Numbers can be either floating point or integer.  I've also skipped lines
% for visual clarity, even among alternative right hand sides.

% This is the most current form of the grammar; grammar.bnf is older and
% contains the quandries about <compound_statement> we resolved.  Kazic, 5.1.01.




% syntax is:

% nonterminal is represented as	<string>

% terminal is in UPPERCASE or between '' (e.g. '*')

% a text description is just a plain string

% comments begin with %



% Kazic. 11.4.00. and 8.8.00.



<transmission>           ::=   <ltransdelim> <statement> <rtransdelim>


<statement>              ::=   <simple_statement> 
                               | <compound_statement> 
                               | <statement> <op> <simple_statement>

                               | <llistdelim> <statement> <rlistdelim>


                               | <lgpdelim> <statement> <rgdelim>

                               | <op> <statement> 
                               | <ifop> <statement> <thenop> <statement>
                               | <ifop> <statement> <thenop> <statement> 
                                         <elseop> <statement>
                               | <forop> <lgpdelim> <statement> <rgpdelim> 
                                         <doop> <lgpdelim> <statement> <rgpdelim>









<compound_statement>     ::=   <simple_statement> <op> <simple_statement>
                               | <embedded_statement>
                               | <compound_statement> <op> <simple_statement>
                               | FUNCTOR <ltupdelim> <compound_statement> <rtupdelim>








<embedded_statement>     ::=   FUNCTOR <ltupdelim> <simple_statement> <rtupdelim>
                               | FUNCTOR <ltupdelim> <embedded_statement> <op> 
                                         <simple_statement> <rtupdelim>
                               | FUNCTOR <ltupdelim> <lgpdelim> <embedded_statement> 
                                         <op> <simple_statement> <rgpdelim> 
                                         <rtupdelim>








<simple_statement>       ::=   FUNCTOR <ltupdelim> <arguments> <rtupdelim>

% the null statement; how this is coded likely depends on the particular
% parser's language

                               | <epsilon>
                               | FUNCTOR <ltupdelim> <simple_statement> <sepop> 
                                         <arguments> <rtupdelim>






FUNCTOR                  ::=   alphanumeric, underscore string beginning with 
                                      lower-case letter




<arguments>              ::=   <argument>
                               | <arguments> <sepop> <argument>
                               | <llistdelim> <arguments> <sepop> <argument> 
                                       <rlistdelim>
                               | <ltupdelim> <arguments> <rtupdelim>




<argument>               ::=   <variable>
                               | <ground>



<ground>                 ::=   <notop> <variable>
                               | <epsilon>


<variable>               ::=   <variablefunc> <ltupdelim> VARIABLE <rtupdelim>



<variablefunc>           ::=   'variable'


VARIABLE                 ::=   alphanumeric string


<epsilon>                ::=    empty string, atom, term, or functor






<delimiter>              ::=    <left_delimiter> 
                                | <right_delimiter>


<left_delimiter>         ::=    <ltransdelim> 
                                | <llistdelim> 
                                | <ltupdelim> 
                                | <lgpdelim>


<right_delimiter>        ::=    <rtransdelim> 
                                | <rlistdelim> 
                                | <rtupdelim> 
                                | <rgpdelim>


<ltransdelim>            ::=   '{'
<rtransdelim>            ::=   '}'
<ltupdelim>              ::=   '('
<rtupdelim>              ::=   ')'
<llistdelim>             ::=   '['
<rlistdelim>             ::=   ']'
<lgpdelim>               ::=   '( '
<rgpdelim>               ::=  ' )'





<op>                     ::=    FUNCTOR
                                | <commentop>
                                | <defop>
                                | <orop>
                                | <elseop>

                                | <ifop>
                                | <thenop>
                                | <forop>
                                | <doop>

                                | <andop>
                                | <notop>

                                | <varassignop>
                                | <numassignop>
                                | <leop>
                                | <gtop>
                                | <leeqop>
                                | <gteqop>

                                | <numeqop>
                                | <stringeqop>
                                | <numneqop>
                                | <stringneqop>

                                | <addop>
                                | <subtractop>
                                | <minusop>
                                | <multop>
                                | <divideop>
                                | <modop>
                                | <expop>

                                | <setop>
                                | <unionop>
                                | <intersectnop>
                                | <arrayop>
                                | <hashop>
                                | <sepop>
                                | <stopop>






% Operator classification

% The greater the precedence integer, the higher
% the precedence.  Semantics follows the common programming standards; different 
% operators are used to assign values to variables and to assign the numerical result
% of a computed expression to a variable.  Similarly, different operators are used
% for numerical and string comparisons.  No standard string comparison operators have
% been assigned since string sort criteria seem to vary among programming languages.

% The 'surround' operator type is really a prefix operator but with a closing right
% parenthesis; both must be present.  It's written this way for tokenizer benefit.



% Notice that many of these operators are for embedding Glossa code within a
% transmission, NOT for simply reporting back what the computed value of some
% variable is.  So, do not misread = as a Variable = ComputedValue statement.
% Instead, values which have been computed are returned wrapped in their corresponding
% functor, JUST AS they are when the values are input in a transmission.
%
% Kazic, 17.1.02.


nonterminal          terminal                type                assoc   precedence

<commentop>   ::=        '%'                  prefix             right     1400
<defop>       ::=        ':-'                 infix              none      1200
<orop>        ::=        '||'                 infix              right     1100
<elseop>      ::=        'else'               prefix             right     1100

<ifop>        ::=        'if'                 prefix             right     1050
<thenop>      ::=        'then'               prefix             right     1050
<forop>       ::=        'for'                prefix             right     1050
<doop>        ::=        'do'                 prefix             right     1050

<andop>       ::=        '&&'                 infix              right     1000
<notop>       ::=        '!'                  prefix             right      900

<varassignop> ::=        '='                  infix              none       700
<numassignop> ::=        'is'                 infix              none       700
<leop>        ::=        '<'                  infix              none       700
<gtop>        ::=        '>'                  infix              none       700
<leeqop>      ::=        '=<'                 infix              none       700
<gteqop>      ::=        '>='                 infix              none       700

<numeqop>     ::=        '=='                 infix              none       700
<stringeqop>  ::=        'eq'                 infix              none       700
<numneqop>    ::=        '!='                 infix              none       700
<stringneqop> ::=        'neq'                infix              none       700

<addop>       ::=        '+'                  infix              left       500
<subtractop>  ::=        '-'                  infix              left       500
<minusop>     ::=        '-'                  prefix             right      500
<multop>      ::=        '*'                  infix              left       400
<divideop>    ::=        '/'                  infix              left       400
<modop>       ::=        'mod'                infix              none       300
<expop>       ::=        '^'                  infix              right      200

<setop>       ::=        'setof(' ')'         surround           interior   100
<unionop>     ::=        'union(' ')'         surround           interior   100
<intersectnop> ::=       'intersection(' ')'  surround           interior   100
<arrayop>     ::=        '@@'                 prefix             right      100
<hashop>      ::=        '%%'                 prefix             right      100
<sepop>       ::=        ','                  infix              none       50
<stopop>      ::=        '.'                  postfix            left       20